@PROMPT $g$s

  setlocal

rem ------------------------------------------------------------------
rem     EXEPATH : Advance CAD の実行形式の格納ディレクトリ
rem               実際のディレクトリに合うように修正すること
rem     PAS     : 第一引数 : コンフィグレーションファイル名
rem     SCR     : 第二引数 : プロットファイル名（スクラッチファイル）
rem     OPT     : 第三引数 : オンラインプロットで指定されたパラメータ
rem ------------------------------------------------------------------

  set EXEPATH=C:\acad\exe
  set PAS=%1
  set SCR=%2
  set OPT=%3

rem ------------------------------------------------------------------
rem     プロットファイルがなければエラー終了
rem ------------------------------------------------------------------

  if not exist %SCR%  goto error1

rem ------------------------------------------------------------------
rem     第三引数によって処理を分岐する
rem     無指定 ならば plot1 : Windows 上のプリンタへの出力例
rem     PLOT1  ならば plot1 : Windows 上のプリンタへの出力例
rem     PLOT2  ならば plot2 : Soralis 2.4 以前のキューへの出力例
rem     PLOT3  ならば plot3 : Windows 版でサポートされていないプロッタ
rem                           への出力例
rem     TIFF   ならば tiff  : TIFF G4 形式のファイル出力の例
rem     その他 ならば エラー終了
rem ------------------------------------------------------------------

  if (%OPT%) == ()      goto plot1
  if (%OPT%) == (PLOT1) goto plot1
  if (%OPT%) == (PLOT2) goto plot2
  if (%OPT%) == (PLOT3) goto plot3
  if (%OPT%) == (TIFF)  goto tiff
  if (%OPT%) == (SET)   goto setput
  goto error2

rem ------------------------------------------------------------------
rem     Windows 上に定義されたプリンタに出力する場合
rem     HP-GL/2 フォーマットの例
rem ------------------------------------------------------------------

:plot1

  set PRG=ap_HPGL.exe
  set PRM=HP-DJET-RTL.PRM
  set QUE=\\pc1\HPGL

  %EXEPATH%\%PRG% -p%PAS% -i%PRM% %SCR% -j%QUE%
  del %SCR%

  goto quit

rem ------------------------------------------------------------------
rem     Solaris 2.4以前のプリントキューに出力する場合
rem     LIPS フォーマットの例
rem ------------------------------------------------------------------

:plot2

  set PRG=ap_LIPS.exe
  set HOST=sun01
  set RQUE=a304
  set PRM=A304.PRM
  set DATA=OPLOT_%COMPUTERNAME%

  %EXEPATH%\ap_LIPS.exe -p%PAS% -i%PRM% %SCR% -o%TEMP%\%DATA%
  del %SCR%

  rcp -b %TEMP%\%DATA% %HOST%:/tmp/%DATA%
  del %TEMP%\%DATA%
  rsh %HOST% "(lp -d %RQUE% -o nobanner < /tmp/%DATA%; rm /tmp/%DATA%)"

  goto quit

rem ------------------------------------------------------------------
rem     Windows 版でサポートされていないプロッタに出力する場合
rem     (UNIX WS 側に rplot シェルスクリプトを用意してください)
rem ------------------------------------------------------------------

:plot3

  set HOST=sun02
  set RPLOT=/home/acad/exe/rplot
  set DATA=OPLOT_%COMPUTERNAME%.SCR

  copy %SCR% %TEMP%\%DATA%
  del %SCR%

  rcp -b %TEMP%\%DATA% %HOST%:/tmp/%DATA%
  del %TEMP%\%DATA%
  rsh %HOST% "%RPLOT% /tmp/%DATA%"

  goto quit

rem ------------------------------------------------------------------
rem     TIFF G4 形式のファイルを出力する場合
rem     第４引数は出力ファイル名（sample\MACRO\TIFF-OUT.MAC を参照）
rem ------------------------------------------------------------------

:tiff

  set TIFF_NAME=%4
  if (%TIFF_NAME%) == () set TIFF_NAME=NONAME.TIFF
  set HPGL_NAME=%TIFF_NAME%_hpgl

  %EXEPATH%\ap_HPGL.exe -p%PAS% -iHP2XX.PRM -m-4.0 %SCR% > %HPGL_NAME%
  del %SCR%

  %EXEPATH%\hp2xx.exe -m tiff -f %TIFF_NAME% -d400 -t %HPGL_NAME%
  del %HPGL_NAME%

  goto quit

:setput
	notepad %PAS%
	del %SCR%
  	goto quit

rem ------------------------------------------------------------------

:error1

  echo scratch file %SCR% not found
  goto quit

rem ------------------------------------------------------------------

:error2

  echo unknown argument
  goto quit

rem ------------------------------------------------------------------

:quit

  endlocal